Note that the Dir function returns files in an unpredictable order so the files will probably not have the same alphabetical order. If you need that, load the whole list of files and sort it before processing the names.

Private Sub cmdGo_Click()
Dim directory As String
Dim filename As String
Dim filenames As New Collection
Dim prefix As String
Dim i As Integer
Dim Index As Integer
Dim pos As Integer
Dim extension As String
Dim new_name As String
Dim mask As String

    MousePointer = vbHourglass

    mask = txtMask.Text
    directory = Trim$(txtDirectory.Text)
    If Right$(directory, 1) <> "\" Then _
        directory = directory & "\"

    ' Get the file names.
    filename = Dir(directory & "*.*")
    Do While filename <> ""
        filenames.Add filename
        filename = Dir
    Loop
    
    ' Rename the files.
    Index = CInt(txtNumberFrom.Text)
    prefix = Trim$(txtPrefix.Text)
    For i = 1 To filenames.Count
        filename = filenames(i)
        pos = InStr(filename, ".")
        If pos > 0 Then
            extension = Right$(filename, Len(filename) - _
                pos + 1)
        Else
            extension = ""
        End If
        Name directory & filename As _
             directory & prefix & _
                Format$(Index, mask) & extension
        Index = Index + 1
    Next i

    MousePointer = vbDefault
    MsgBox "Moved" & Str$(filenames.Count) & " files."
    File1.Refresh
End Sub